|
三角形单元与矩形单元的精细网格的计算比较
针对【典型例题】4.3.2(3)的问题，在ANSYS平台上，进行三角形单元与矩形单元的精细网格的划分，完成相应的力学分析。
(a)采用三角形单元的划分
(b)采用四边形单元的划分
图4-11 基于ANSYS平台的精细网格划分(每边划分10段)
解答：下面基于ANSYS平台，进行三角形单元与矩形单元的精细网格的划分，见图4-11。对该问题进行有限元分析的过程如下。
1 基于图形界面(GUI)的交互式操作(step by step)
(1) 进入ANSYS（设定工作目录和工作文件）
程序 → ANSYS → ANSYS Interactive → Working directory（设置工作目录）→ Initial jobname（设置工作文件名）: TrussBridge → Press → Run → OK
(2) 设置计算类型
ANSYS Main Menu: Preferences… → Structural → OK
(3) 定义分析类型
ANSYS Main Menu: Preprocessor → Loads → Analysis Type → New Analysis→ STATIC → OK
(4) 定义材料参数
ANSYS Main Menu: Preprocessor → Material Props → Material Models →Structural → Linear → Elastic → Isotropic → EX: 1（弹性模量), PRXY: 0.25(泊松比)→ OK → 鼠标点击该窗口右上角的“×”来关闭该窗口
(5)定义单元类型
ANSYS Main Menu: Preprocessor → Element Type → Add/Edit/Delete... → Add…→ Structural Solid: Quad 4node 42 → OK（返回到Element Types窗口）→ Close
(6)设置为带厚度的平面问题
ANSYS Main Menu: Preprocessor →Real Constants… →Add/Edit/Delete →Add →Type 1→ OK→Real Constant Set No: 1 (第1号实常数), THK: 1 (平面问题的厚度) →OK →Close
(7) 定义实常数以确定厚度
ANSYS Main Menu: Preprocessor → Real Constants…→ Add…→ Type 1 Plane42 → OK → Real Constants Set No: 1（第1号实常数）, Thickness: 1（平面问题的厚度）→ OK → Close
(8) 构造模型
生成几何模型
ANSYS Main Menu: Preprocessor → Modeling → Create → Keypoints → In Active CS → Keypoint number：1，X，Y，Z Location in active CS：0,0,0 → Apply → （同样方式输入其余3个特征点坐标，分别为 (1,0,0), (1,1,0), (0,1,0) ）→ OK
连接点生成面
ANSYS Main Menu: Preprocessor → Modeling → Create → Areas → Arbitrary → Through KPs → Min，Max，Inc： 1,4,1 →OK
(9) 设定模型材料
ANSYS Main Menu: Preprocessor → Modeling → Create → Elements → Elem Attributes → MAT: 1 ,TYPE: 1 PLANE42 , REAL: 1 →OK
(10) 网格划分
ANSYS Utility Menu: Select → Entities → Sele lines → Sele All → OK
ANSYS Main Menu: Preprocessor → Meshing → Size Cntrls → ManualSize → Lines → All Lines→ Element Sizes on All Seleceted Lines: NDIV: 10 (每一条线分为10段) ，SPACE: 1 → OK →ANSYS Main Menu：Preprocessor → Meshing → MeshTool → Mesh：Areas，Shape：Tri，mapped → Mesh → Pick ALL
(11) 模型加约束
ANSYS Utility Menu: Select → Everything
ANSYS Main Menu: Preprocessor → Loads → Define Loads → Apply → Structural → Displacement → On Keypoints→Min，Max，Inc： 1 → OK → lab2：ALL DOF(约束1号特征点所有方向上的位移) → Apply → Min，Max，Inc： 4 → OK → lab2：UX(约束4号特征点X方向上的位移) → OK
(12) 施加载荷
在2号特征点上施加负X方向的外载：
ANSYS Main Menu: Preprocessor → Loads → Define Loads → Apply → Structural → Force/Moment → On Keypoints → Min，Max，Inc： 2 → OK → Direction of force/mom: FX , Force/moment value: -1 →Apply
在3号节点上施加X方向的外载：
ANSYS Main Menu: Preprocessor→ Loads → Define Loads → Apply → Structural → Force/Moment→ On Keypoints → Min，Max，Inc： 3 → OK → Direction of force/mom: FX，Force/moment value: 1 → OK
(13) 计算分析
ANSYS Main Menu: Solution → Solve → Current LS → OK
(14) 结果显示
显示变形前后的位移：
ANSYS Main Menu: General Postproc → Plot Results → Deformed shape → Def + undeformed → OK
ANSYS Utility Menu: Parameters →Scalar Parameters → Selection下输入NB=NODE(1,0,0) → Accept → (以同样方式输入其余需要的结果参数表达式，分别为NB_UX=UX(NB)；NB_UY=UY(NB)；NC=NODE(1,1,0)；NC_UX=UX(NC) ；NC_UY=UY(NC)；STR_ENGY= 0.5*(NB_UX*(-1)+ NC_UX*(1))；POTE_ENGY=-0.5*(NB_UX*(-1)+ NC_UX*(1)) ) → Close
ANSYS Utility Menu: List → Status → Parameters → All Parameters（显示所有计算结果）
(15) 退出系统
ANSYS Utility Menu: File → Exit → Save Everything → OK
2 完整的命令流
/PREP7 !进入前处理
ANTYPE,STATIC !设定为静态分析
MP,EX,1,1 !定义1号材料的弹性模量
MP,PRXY,1,0.25 !设定1号材料的泊松比
ET,1,PLANE42 ! 选取单元类型1
KEYOPT,1,3,3 !设置为带厚度的平面问题
R,1,1 ! 设定实常数No.1，厚度
K,1,0,0,0 !生成几何点No.1
K,2,1,0,0 !生成几何点No.2
K,3,1,1,0 !生成几何点No.3
K,4,0,1,0 !生成几何点No.4
A,1,2,3,4 !由几何点连成几何面No.1
MAT,1 ! 设定为材料No.1
TYPE,1 ! 设定单元No.1
REAL,1 ! 设定实常数No.1
!------设置单元划分
LSEL,ALL !选择所有的线
LESIZE,all, , ,10, , , , ,1 !将所选择的线划分成10段
MSHAPE,1,2D !设置三角形单元
!MSHAPE,0,2D !设置四边形单元
MSHKEY,1 !设置映射划分
AMESH,1 !对面No.1进行网格划分
ALLSEL,ALL !选择所有的对象
DK,1,ALL ! 对几何点1施加固定的位移约束
DK,4,ALL ! 对几何点4施加固定的位移约束
FK,2,FX,-1 ! 对几何点2施加外力FX=-1
FK,3,FX,1 ! 对几何点3施加外力FX=1
FINISH !结束前处理
/SOLU !进入求解模块
SOLVE !求解
FINISH !结束求解
/POST1 !进入后处理
PLDISP,1 !计算的变形位移显示(变形前与后的对照)
NB=NODE(1,0,0) !获取几何位置为(1,0,0) (B点)所对应的节点号码，赋值给NB
NB_UX=UX(NB) !获取节点号NB处的位移UX，赋值给NB_UX
NB_UY=UY(NB) !获取节点号NB处的位移UY，赋值给NB_UY
ALLSEL,ALL ! 选择所有的对象
NC=NODE(1,1,0) ! 获取几何位置为(1,1,0) (C点)所对应的节点号码，赋值给NC
NC_UX=UX(NC) ! 获取节点号NC处的位移UX，赋值给NC_UX
NC_UY=UY(NC) !获取节点号NC处的位移UY，赋值给NC_UY
STR_ENGY= 0.5*(NB_UX*(-1)+ NC_UX*(1)) !计算结构系统的应变能
POTE_ENGY=-0.5*(NB_UX*(-1)+ NC_UX*(1)) ! 计算结构系统的势能
*status,parm !显示所有的参数
以下为计算结果：
采用三角形单元(每边分为10段)
NAME VALUE TYPE DIMENSIONS
NB 2.00000000 SCALAR
NB_UX -9.56063701 SCALAR
NB_UY -9.36565959 SCALAR
NC 12.0000000 SCALAR
NC_UX 9.88621794 SCALAR
NC_UY -10.0535107 SCALAR
POTE_ENGY -9.72342747 SCALAR
STR_ENGY 9.72342747 SCALAR
采用四边形单元(每边分为10段)
NAME VALUE TYPE DIMENSIONS
NB 2.00000000 SCALAR
NB_UX -12.6893715 SCALAR
NB_UY -12.6893715 SCALAR
NC 12.0000000 SCALAR
NC_UX 12.6893715 SCALAR
NC_UY -12.6893715 SCALAR
POTE_ENGY -12.6893715 SCALAR
STR_ENGY 12.6893715 SCALAR
根据上面计算的POTE_ENGY参数，有以下的结果。
采用如图4-11(a)所示三角形单元网格划分计算得到的该系统的势能为
U-W-9.72342747Π== (4-78)
采用如图4-11(b)所示矩形单元网格划分计算得到的该系统的势能为
U-W-12.6893715Π== (4-79)
若比较式(4-72)、式(4-77)、式(4-78)与式(4-79)，读者完全可以对各个计算方案的计算精度有一个比较明确的评判和结论。
|